Suppose there are a finite number of primes and they are p1, p2, ..., pn. Then none of can divide the value:

    p1 * p2 * ... * Pn + 1

So this new number is also prime, contradicting the assumption that p1, p2, ..., pn are all of the primes.

Recently someone suggested a similar technique for finding a big prime. The idea is to take the product of the first N primes and then add or subtract 1.

Unfortunately this method doesn't work. While the new number is not divisible by the primes you use to build the number, there may be other primes beyond those (but still smaller than the square root of the new number) that divide it.

This program demonstrates this by calculating products of the first N primes and then finding their prime factors.

The following code shows the program's Form_Load event handler. It calculates products of the first 1, 2, ..., 9 primes and calls function Factors to display their prime factors.

Private Sub Form_Load()
Dim primes() As String
Dim result As String
Dim i As Integer
Dim j As Integer
Dim num As Long
Dim txt As String

    primes = Split("2,3,5,7,11,13,17,19,23", ",")
    result = ""
    
    For i = LBound(primes) To UBound(primes)
        num = 1
        txt = ""
        For j = LBound(primes) To i
            txt = txt & " x " & primes(j)
            num = num * CLng(primes(j))
        Next j
        txt = Mid$(txt, 3)
        num = num - 1
        result = result & txt & " - 1 = " & Format$(num) & _
            " = " & Factors(num) & vbCrLf
        num = num + 2
        result = result & txt & " + 1 = " & Format$(num) & _
            " = " & Factors(num) & vbCrLf
    Next i

    txtResult.Text = result
    txtResult.SelStart = 0
    txtResult.SelLength = 0
End Sub

The function starts by pulling factors of 2 out of the number. As long as the number is divisible by 2, the program adds a 2 to the output and divides the number by 2.

Eventually the number becomes odd (there may be remaining odd factors or, if the number is a power of two, then this step reduces the number to 1). At that point, the program starts pulling out odd factors. Starting with the test factor value 3, if the test factor value divides the number evenly, then the program adds it to the output and divides the test factor from the number. If the test factor doesn't divide the number evenly, then the program adds 2 to the test factor to consider the next odd number.

The program repeats this step until the test factor is greater than the square root of the remaining number. At that point, whatever is left of the number is prime.

' Return the number's prime factors.
Private Function Factors(ByVal num As Long) As String
    Dim result As String
    result = ""

    ' Take out the 2s.
    Do While num Mod 2 = 0
        ' This is a factor.
        result = result & " x 2"
        num = num \ 2
    Loop

    ' Take out other primes.
    Dim factor As Long
    factor = 3
    Do While factor * factor <= num
        If num Mod factor = 0 Then
            ' This is a factor.
            result = result & " x " & Format$(factor)
            num = num \ factor
        Else
            factor = factor + 1
        End If
    Loop

    If num > 1 Then result = result & " x " & Format$(num)
    If Len(result) = 0 Then
        result = "1"
    Else
        result = Mid$(result, 3)
    End If

    Factors = result
End Function

     2 x 3 x 5 x 7 - 1 = 209 =  11 x 19

The first example that p1 * p2 * ... * pn + 1 is non prime is:

      2 x 3 x 5 x 7 x 11 x 13 + 1 = 30031 =  59 x 509

Also look here for an interesting article about the largest known prime number (as of September 28, 2008). It has around 13 million digits!